Scripts

Copy & paste

--Copy and paste script
--Author: Ben Bryan
--Created: 20/10/05
--Updated: 06/04/11

macroScript Copy
category:"MaxPack"
toolTip:"Copy"
icon:#("copy&paste", 1)
(
	on isEnabled do
	(
		return selection.count != 0
	)

	on execute do
	(		
		max_temp = pathConfig.appendPath (GetDir #temp) "copy&paste.max"
		
		if selection.count != 0 then
		(
			saveNodes selection max_temp
		)
	)
)

macroScript ForceCopy
category:"MaxPack"
buttonText:"Copy(force)"
toolTip:"Copy(force)"
icon:#("copy&paste", 3)
(
	on isEnabled do
	(
		return selection.count != 0
	)

	on execute do
	(		
		max_temp = pathConfig.appendPath (GetDir #temp) "copy&paste.max"
		
		if selection.count != 0 do
		(	
			a = selection as array
			inv_array = #()
			
			for obj in objects do
			(
				exists = false
				
				for s in a do 
				(
					if obj == s then
					(
						exists = true		
					)
				)
				
				if exists == false do append inv_array obj
			)	
			
			if inv_array.count != 0 then
			(
				delete inv_array	
				saveMaxFile max_temp clearNeedSaveFlag:false useNewFile:false quiet:true
				max undo
			)	

		)
	)
)

macroScript Paste
category:"MaxPack"
toolTip:"Paste"
icon:#("copy&paste", 2)
(	
	max_temp = pathConfig.appendPath (GetDir #temp) "copy&paste.max"	
	mergeMAXFile max_temp #mergeDups #select
)